Controller Script
Interval = .6 

[*E -]
[F1 CT +3]	send sample holder T every 3 sec
[F1 HT +10]	send heat exchanger T every 10 sec 
		(monitors coolant T)
[F1 SS S 500]	set stirring to 500 rpm
		(also turns stirring on)
	----------do a baseline correction
[*MSG - Put blank (buffer) into the sample holder, close lid, click OK]
[*CTD]		clear the displays
[*SS +]		begin collecting absorbance data
[*SC h600, 300]	set scan range
[*SC c0]	do baseline correction
		(returns to 600 nm when done)
[*D 100]	allow 1 min to finish
[*SW 600]	tell T-App(S) what the current wavelength is
	----------equilibrate sample to starting temperature
[F1 TT S 10]	set target to 10 C
[F1 TC +]	turn temperature control on
[*MSG - Put Methyl Orange sample in sample holder, close lid, click OK]
[*WT 1000 2]	wait for stable T (or 20 min)
[*D 500]	wait 5 min for sample to catch up

[F1 CT -]	stop automatic sending of holder T
[*SS +]		begin collecting absorbance data
		(just in case user stopped collection)
[*CTD]		clear the displays

	----------do a scan at 10C (600 to 300, 2.5 nm steps)
[*LS 121]	begin loop: 121=(600-300)/2.5+1
   [F1 CT ?]	   request sample holder T
   [*SW- 2.5]	   decrement wavelength
   [*D 1]	   wait 0.01 min
[*LE]

	----------ramp 10 to 60 at 1/min, monitor 500, 400 nm
[*SW 500]	set wavelength to 500 nm
[*D 50]		wait 0.5 min
[F1 RR S 1]	set ramp rate to 1 C
[F1 TT S 60]	set target T to 60 (starts ramp)
[*LS 52]	loop 52 times (about 52 min)
		(each loop starts at 500 nm)
   [F1 CT ?]	   request sample holder T
   [*SW 400]	   set 630 nm
   [*D 5]	   wait 0.05 min
   [F1 CT ?]	   request sample holder T
   [*SW 500]	   set 500 nm
   [*D 90]	   wait 0.90 min
[*LE]		end of loop

	----------do a scan at 60C (600 to 300, 2.5 nm steps)
[*SW 600]	set wavelength to 600 nm
[*D 50]		wait 0.5 min
[*LS 121]	begin loop: 121=(600-300)/2.5+1
   [F1 CT ?]	   request sample holder T
   [*SW- 2.5]	   decrement wavelength 2.5 nm
   [*D 1]	   wait 0.01 min
[*LE]		end of loop

[*SW 550]
[F1 HT -]	stop sending heat exchanger T
[F1 TC -]	turn temperature control off
[*MSG + Script run is complete] 
